midinoteonoct
Prev | Orchestra Opcodes and Operators | Next

## midinoteonoct

midinoteonoct — Gets a MIDI note number value as octave-point-decimal value.

## Description

midinoteonoct is designed to simplify writing instruments that can be used interchangeably for either score or MIDI input, and to make it easier to adapt instruments originally written for score input to work with MIDI input.

In general, it should be possible to write instrument definitions that work identically with both scores and MIDI, including both MIDI files and real-time MIDI input, without using any conditional statements, and that take full advantage of MIDI voice messages.

Note that correlating Csound instruments with MIDI channel numbers is done using the massign opcode for real-time performance,. For file-driven performance, instrument numbers default to MIDI channel number + 1, but the defaults are overridden by any MIDI program change messages in the file.

## Syntax

    midinoteonoct xoct, xvelocity

## Performance

xoct -- returns MIDI key translated to linear octaves during MIDI activation, remains unchanged otherwise.

xvelocity -- returns MIDI velocity during MIDI activation, remains unchanged otherwise.

If the instrument was activated by MIDI input, the opcode overwrites the values of xoct and xvelocity with the corresponding value from MIDI input. If the instrument was NOT activated by MIDI input, the values of xoct and xvelocity remain unchanged.

This enables score p-fields to receive MIDI input data during MIDI activation, and score values otherwise.

| Adapting a score-activated Csound instrument.
See the MIDI interop opcodes section for details on adapting score driven instruments for MIDI or vice-versa.

## Examples

Here is an example of the midinoteonoct opcode. It uses the file midinoteonoct.csd.

Example 578. Example of the midinoteonoct opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    -M1  ;;;realtime audio out and midi in
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o midinoteonoct.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    midinoteonoct p4, p5			;gets a MIDI note number value as octave-point-decimal value into p4, and MIDI velocity into p5

    print 	p4				;display the key value when it changes and when key is pressed
    kvel = p5/127				;scale midi velocity to 0-1
    ioct =	p4
    icps =	cpsoct(ioct)			;convert octave-point-decimal value into Hz
    kenv madsr 0.5, 0.8, 0.8, 0.5		;amplitude envelope multiplied by
    asig pluck kenv*kvel, icps, icps, 2, 1	;velocity value
         outs  asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 0 30	;runs for 30 seconds
    f 2 0 4096 10 1

    i 1 0 2 8.000 100	; play these notes from score as well
    i 1 + 2 8.917 100
    e

    </CsScore>
    </CsoundSynthesizer>

Its output should include lines like:

     i1     8.00000
     i1     8.91700
     i1     9.33333

## See Also

midichannelaftertouch, midicontrolchange, mididefault, midinoteoff, midinoteoncps, midinoteonkey, midinoteonpch, midipitchbend, midipolyaftertouch, midiprogramchange

## Credits

Author: Michael Gogins

New in version 4.20

Prev | Up | Next
midinoteonkey | Home | midinoteonpch