wgbrass
Prev | Orchestra Opcodes and Operators | Next

## wgbrass

wgbrass — Creates a tone related to a brass instrument.

## Description

Audio output is a tone related to a brass instrument, using a physical model developed from Perry Cook, but re-coded for Csound.

## Syntax

    ares wgbrass kamp, kfreq, ktens, iatt, kvibf, kvamp \
        [, ifn] [, iminfreq]

## Initialization

iatt -- time taken to reach full pressure

ifn -- optional table of shape of vibrato, defaults to a sine table.

iminfreq -- lowest frequency at which the instrument will play. If it is omitted it is taken to be the same as the initial kfreq. If iminfreq is negative, initialization will be skipped.

## Performance

A note is played on a brass-like instrument, with the arguments as below.

kamp -- Amplitude of note.

kfreq -- Frequency of note played.

ktens -- lip tension of the player. Suggested value is about 0.4

kvibf -- frequency of vibrato in Hertz. Suggested range is 0 to 12

kvamp -- amplitude of the vibrato

| NOTE
This is rather poor, and at present uncontrolled. Needs revision, and possibly more parameters.

## Examples

Here is an example of the wgbrass opcode. It uses the file wgbrass.csd.

Example 1168. Example of the wgbrass opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o wgbrass.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    ksmps = 10
    nchnls = 1
    0dbfs = 1

    ; Instrument #1.
    instr 1
      kamp = 0.7
      kfreq = p4
      ktens = p5
      iatt = p6
      kvibf = p7
      ifn = 1

      ; Create an amplitude envelope for the vibrato.
      kvamp line 0, p3, 0.5

      a1 wgbrass kamp, kfreq, ktens, iatt, kvibf, kvamp, ifn
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 1024 10 1

    ;        freq   tens  att  vibf
    i 1 0 4  440    0.4   0.1  6.137
    i 1 4 4  440    0.4   0.01 0.137
    i 1 8 4  880    0.4   0.1  6.137
    e

    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: John ffitch (after Perry Cook)
University of Bath, Codemist Ltd.
Bath, UK

New in Csound version 3.47

ifn optional in 6.06

Prev | Up | Next
wgbowedbar | Home | wgclar