vdelay3
Prev | Orchestra Opcodes and Operators | Next

## vdelay3

vdelay3 — A variable time delay with cubic interpolation.

## Description

vdelay3 is experimental. It is the same as vdelay except that it uses cubic interpolation. (New in Version 3.50.)

## Syntax

    ares vdelay3 asig, adel, imaxdel [, iskip]

## Initialization

imaxdel -- Maximum value of delay in milliseconds. If adel gains a value greater than imaxdel it is folded around imaxdel. This should not happen.

iskip (optional) -- Skip initialization if present and non-zero.

## Performance

With this unit generator it is possible to do Doppler effects or chorusing and flanging.

asig -- Input signal.

adel -- Current value of delay in milliseconds. Note that linear functions have no pitch change effects. Fast changing values of adel will cause discontinuities in the waveform resulting noise.

## Examples

Here is an example of the vdelay3 opcode. It uses the file vdelay3.csd.

Example 1121. Example of the vdelay3 opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o vdelay3.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ims  = 100			;maximum delay time in msec
    aout poscil .8, 220, 1		;make a signal
    a2   poscil ims/2, 1/p3, 1	;make an LFO
    a2   = a2 + ims/2		;offset the LFO so that it is positive
    asig vdelay3 aout, a2, ims	;use the LFO to control delay time
         outs  asig, asig

    endin

    </CsInstruments>
    <CsScore>
    f1 0 8192 10 1

    i 1 0 5

    e

    </CsScore>
    </CsoundSynthesizer>

Two important points here. First, the delay time must be always positive. And second, even though the delay time can be controlled in k-rate, it is not advised to do so, since sudden time changes will create clicks.

## See Also

vdelay

## Credits

Author: Paris Smaragdis
MIT, Cambridge
1995

Prev | Up | Next
vdelay | Home | vdelayx