vtablek
Prev | Orchestra Opcodes and Operators | Next

## vtablek

vtablek — Read vectors (from tables -or arrays of vectors).

## Description

This opcode reads vectors from tables at k-rate.

## Syntax

    vtablek  kndx, kfn, kinterp, ixmode, kout1 [, kout2, kout3, .... , koutN ]

## Initialization

ixmode - index data mode. The default value is 0.

== 0 index is treated as a raw table location,

== 1 index is normalized (0 to 1).

kinterp - switch beetween interpolated or non-interpolated output. 0 -> non-interpolation , non-zero -> interpolation activated

## Performance

kndx - Index into f-table, either a positive number range matching the table length (ixmode = 0) or a 0 to 1 range (ixmode != 0).

kfn - table number

kout1...koutN - output vector elements

This opcode is useful in all cases in which one needs to access sets of values associated to unique indexes (for example, multi-channel samples, STFT bin frames, spectral formants, p-field based scores etc.). The number of elements of each vector (length of the vector) is determined by the number of optional arguments on the right (kout1 , kout2, kout3, .... koutN).

vtablek allows the user to switch beetween interpolated or non-interpolated output at k-rate by means of kinterp argument.

vtablek allows also to switch the table number at k-rate (but this is possible only when vector frames of each used table have the same number of elements, otherwise unpredictable results could occurr), as well as to choose indexing style (raw or normalized, see also ixmode argument of table opcode ).

Notice that no wrap nor limit mode is implemented. So, if an index attempt to access to a zone not allocated by the table, Csound will probably crash. However this drawback can be easily avoided by using wrap or limit opcodes applied to indexes before using vtable, in order to correct eventual out-of-range values.

| Note
Notice that vtablek's output arguments are placed at the left of the opcode name, differently from usual (this style is already used in other opcodes using undefined lists of output arguments such as fin or trigseq).

## Examples

Here is an example of the vtablek opcode. It uses the files vtablek.csd.

Example 1160. Example of the vtablek opcode.

    <CsoundSynthesizer>
    <CsOptions>
    -odac -B441 -b441
    </CsOptions>
    <CsInstruments>

    sr     =        44100
    kr     =        100
    ksmps  =        441
    nchnls =        2

    gkindx init -1

           instr    1
    kindex init 0
    ktrig metro 0.5
    if ktrig = 0 goto noevent
    gkindx = gkindx + 1
    noevent:

    	endin

    	instr	2
    kout1 init 0
    kout2 init 0
    kout3 init 0
    kout4 init 0
    vtablek  gkindx, 1, 1, 0, kout1,kout2, kout3, kout4
    printk2 kout1
    printk2 kout2
    printk2 kout3
    printk2 kout4
    	endin

    </CsInstruments>
    <CsScore>
    f 1 0 32 10 1
    i 1 0 20
    i 2 0 20
    </CsScore>
    </CsoundSynthesizer>

## See also

vtablea, vtablei, vtabk, vtablewk, vtabwk,

## Credits

Written by Gabriel Maldonado.

Example written by Andres Cabrera.

New in Csound 5 (Previously available only on CsoundAV)

Prev | Up | Next
vtablei | Home | vtablea