pchbend
Prev | Orchestra Opcodes and Operators | Next

## pchbend

pchbend — Get the current pitch-bend value for this channel.

## Description

Get the current pitch-bend value for this channel.

## Syntax

    ibend pchbend [imin] [, imax]

    kbend pchbend [imin] [, imax]

## Initialization

imin, imax (optional) -- set minimum and maximum limits on values obtained

## Performance

Get the current pitch-bend value for this channel. Note that this access to pitch-bend data is independent of the MIDI pitch, enabling the value here to be used for any arbitrary purpose.

## Examples

Here is an example of the pchbend opcode. It uses the file pchbend.csd.

Example 708. Example of the pchbend opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac -Q1 -Ma  ;;;realtime audio out and midi in (on all inputs) and out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o pchbend.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr   1	;use external midi keyboard

    icps cpsmidi
    kbnd pchbend 0, 100					;one octave lower and higher
    kenv linsegr 0,.001, 1, .1, 0				;amplitude envelope
    asig pluck .8 * kenv, icps+kbnd, 440, 0, 1
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    f 0 30	;runs 30 seconds

    </CsScore>
    </CsoundSynthesizer>

## See Also

aftouch, ampmidi, cpsmidi, cpsmidib, midictrl, notnum, octmidi, octmidib, pchmidi, pchmidib, veloc

## Credits

Author: Barry L. Vercoe - Mike Berry
MIT - Mills
May 1997

Prev | Up | Next
pcauchy | Home | pchmidi