maxarray
Prev | Orchestra Opcodes and Operators | Next

## maxarray

maxarray — returns the maximum value in an array.

## Description

The maxarray opcode returns the maximum value in a k-rate array, and optional its index.

## Syntax

    kmax [,kindx] maxarray karray

## Performance

kmax -- variable for result.

kindx -- position (index) of result in array.

karray -- array for reading.

## Examples

Here is an example of the maxarray opcode. It uses the file maxarray.csd.

Example 557. Example of the maxarray opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -n
    </CsOptions>
    <CsInstruments>
    ksmps = 32
    ;example by joachim heintz

               seed       0

    instr 1
    ;create an array with 10 elements
    kArr[]     init       10
    ;fill in random numbers and print them out
    kIndx      =          0
      until kIndx == 10 do
    kNum       random     -100, 100
    kArr[kIndx] =         kNum
               printf     "kArr[%d] = %10f\n", kIndx+1, kIndx, kNum
    kIndx      +=         1
      od
    ;investigate maximum number and print it out
    kMax, kMaxIndx maxarray kArr
               printf     "Maximum of kArr = %f at index %d\n", kIndx+1, kMax, kMaxIndx
               turnoff
    endin

    </CsInstruments>
    <CsScore>
    i1 0 0.1
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

minarray, sumarray, scalearray,

## Credits

Author: John ffitch
October 2011

New in Csound version 5.14

Revised in Csound version 6.00 to work on multidimensional arrays

Prev | Up | Next
max_k | Home | mclock