display
Prev | Orchestra Opcodes and Operators | Next

## display

display — Displays the audio or control signals as an amplitude vs. time graph.

## Description

These units will print orchestra init-values, or produce graphic display of orchestra control signals and audio signals. Uses X11 windows if enabled, else (or if -g flag is set) displays are approximated in ASCII characters.

## Syntax

    display xsig, iprd [, inprds] [, iwtflg]

## Initialization

iprd -- the period of display in seconds.

inprds (optional, default=1) -- Number of display periods retained in each display graph. A value of 2 or more will provide a larger perspective of the signal motion. The default value is 1 (each graph completely new). inprds is a scaling factor for the displayed waveform, controlling how many iprd-sized frames of samples are drawn in the window (the default and minimum value is 1.0). Higher inprds values are slower to draw (more points to draw) but will show the waveform scrolling through the window, which is useful with low iprd values.

iwtflg (optional, default=0) -- wait flag. If non-zero, each display is held until released by the user. The default value is 0 (no wait).

## Performance

display -- displays the audio or control signal xsig every iprd seconds, as an amplitude vs. time graph.

## Examples

Here is an example of the display opcode. It uses the file display.csd.

Example 232. Example of the display opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o display.wav -W ;;; for file output any platform
    </CsOptions>;be sure to NOT have -d in the CsOptions...
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1

    kcps = 110
    ifn  = 1

    knh	line p4, p3, p5
    asig	buzz 1, kcps, knh, ifn
    	outs asig, asig

    display	asig, .1, 3

    endin
    </CsInstruments>
    <CsScore>
    ;sine wave.
    f 1 0 16384 10 1

    i 1 0 3 20 20
    i 1 + 3 3 3
    i 1 + 3 150 1
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

dispfft, print

## Credits

Comments about the inprds parameter contributed by Rasmus Ekman.

Prev | Up | Next
dispfft | Home | distort