a
Prev | Orchestra Opcodes and Operators | Next

## a

a — Converts a k-rate parameter to an a-rate value with interpolation.

## Description

Converts a k-rate parameter to an a-rate value with interpolation.

## Syntax

    a(x) (control-rate args only)

where the argument within the parentheses may be an expression. Value converters perform arithmetic translation from units of one kind to units of another. The result can then be a term in a further expression.

## Examples

Here is an example of the a opcode. It uses the file opa.csd.

Example 41. Example of the a opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ;-o a.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; hear the difference between instr.1 and 2
    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1	;sine wave at k-rate

    ksig	oscil 0.8, 440, 1
    ; k-rate to the audio-rate conversion
    asig =  a(ksig)
    	outs asig, asig

    endin

    instr 2	;sine wave at a-rate

    asig	oscil 0.8, 440, 1
    	outs  asig, asig

    endin

    </CsInstruments>
    <CsScore>
    ; sine wave.
    f 1 0 16384 10 1

    i 1 0 2
    i 2 2 2
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

i, k

## Credits

Author: Gabriel Maldonado

New in version 4.21

Prev | Up | Next
# | Home | abs