set dotenv-load

connectivity_db := "artifacts/connectivity.db"
lookup_db := "artifacts/lookups.db"
entities_db := "../deped-entity/artifacts/entities.db"
web_xlsx := "data/2026-04-01-connectivity.xlsx"
web_csv := "artifacts/2026-04-01-connectivity.csv"

# serve documentation
docs:
  uv run zensical serve --dev-addr localhost:8002

# create .env file from example
dumpenv:
  op inject -i env.example -o .env

# upload to pypi
publish:
  uv build && \
  UV_PUBLISH_TOKEN=$PYPI_TOKEN uv publish

# create lookup database from deped-dcp-templates
lookup:
  uv run deped-dcp-template extract \
  --templates-dir templates \
  --output {{lookup_db}}

# extract
extract:
  uv run web extract \
  --xlsx {{web_xlsx}} \
  --csv {{web_csv}}

# create web database from equipment csv and lookup and personnel databases
build:
  uv run web build \
  --connectivity {{web_csv}} \
  --lookups {{lookup_db}} \
  --entities-db {{entities_db}} \
  --db {{connectivity_db}}

# run web pipeline from scratch
restart:
  rm -rf artifacts && \
  just lookup && \
  just extract && \
  just build
